TITLE: 5-wave factor of curves model of general cognitive ability and four cognitive 
ability domains

DATA: FILE = "";!add data file name here
 
! Note that some of the cognitive test scores are scaled so that all test variances are 
! within a similar range. This is to aid model convergence.
! Some of the test slopes' residual variances were near zero and estimated as negative.
! To avoid these out of bounds estimates, residual variances that were estimated as 
! negative are fixed to zero in the model.  
! We use the marker variable method of scale setting.

VARIABLE: 
NAMES = matreas_w1 matreas_w2 matreas_w3 matreas_w4 blkdes_w1 blkdes_w2 blkdes_w3
     blkdes_w4 spantot_w1 spantot_w2 spantot_w3 spantot_w4 vpatotal_w1 vpatotal_w2
     vpatotal_w3 vpatotal_w4 lmtotal_w1 lmtotal_w2 lmtotal_w3 lmtotal_w4 digback_w1
     digback_w2 digback_w3 digback_w4 nart_w1 nart_w2 narttot_w3 narttot_w4
     wtar_w1 wtar_w2 wtartot_w3 wtartot_w4 vftot_w1 vftot_w2 vftot_w3 vftot_w4
     digsym_w1 digsym_w2 digsym_w3 digsym_w4 symsear_w1 symsear_w2 symsear_w3
     symsear_w4 crtmean_w1 crtmean_w2 crtmean_w3 crtmean_w4 ittotal_w1 ittotal_w2
     ittotal_w3 ittotal_w4 matreas_w5 blkdes_w5 spantot_w5 vpatotal_w5 lmtotal_w5
     digback_w5 narttot_w5 wtartot_w5 vftot_w5 digsym_w5 symsear_w5 crtmean_w5
     ittotal_w5; 

USEVARIABLES = matreas_w1 matreas_w2 matreas_w3 matreas_w4 blkdes_w1 blkdes_w2 blkdes_w3
     blkdes_w4 spantot_w1 spantot_w2 spantot_w3 spantot_w4 vpatotal_w1 vpatotal_w2
     vpatotal_w3 vpatotal_w4 lmtotal_w1 lmtotal_w2 lmtotal_w3 lmtotal_w4 digback_w1
     digback_w2 digback_w3 digback_w4 nart_w1 nart_w2 narttot_w3 narttot_w4
     wtar_w1 wtar_w2 wtartot_w3 wtartot_w4 vftot_w1 vftot_w2 vftot_w3 vftot_w4
     digsym_w1 digsym_w2 digsym_w3 digsym_w4 symsear_w1 symsear_w2 symsear_w3
     symsear_w4 crtmean_w1 crtmean_w2 crtmean_w3 crtmean_w4 ittotal_w1 ittotal_w2
     ittotal_w3 ittotal_w4 matreas_w5 blkdes_w5 spantot_w5 vpatotal_w5 lmtotal_w5
     digback_w5 narttot_w5 wtartot_w5 vftot_w5 digsym_w5 symsear_w5 crtmean_w5
     ittotal_w5;

  MISSING  = ALL(-9999); !code missing

!rescaled some of the cognitive test variables so that variances are within a similar 
!range see http://www.statmodel.com/discussion/messages/11/1615.html?1335376547

DEFINE: 
    blkdes_w1 = blkdes_w1/2;
    blkdes_w2 = blkdes_w2/2;
    blkdes_w3 = blkdes_w3/2;
    blkdes_w4 = blkdes_w4/2;
    blkdes_w5 = blkdes_w5/2;
    vftot_w1 = vftot_w1/2;
    vftot_w2 = vftot_w2/2;
    vftot_w3 = vftot_w3/2;
    vftot_w4 = vftot_w4/2;
    vftot_w5 = vftot_w5/2;
    lmtotal_w1 = lmtotal_w1/3;
    lmtotal_w2 = lmtotal_w2/3;
    lmtotal_w3 = lmtotal_w3/3;
    lmtotal_w4 = lmtotal_w4/3;
    lmtotal_w5 = lmtotal_w5/3;
    digback_w1 = 3*digback_w1;
    digback_w2 = 3*digback_w2;
    digback_w3 = 3*digback_w3;
    digback_w4 = 3*digback_w4;
    digback_w5 = 3*digback_w5;
    digsym_w1 = digsym_w1/2;
    digsym_w2 = digsym_w2/2;
    digsym_w3 = digsym_w3/2;
    digsym_w4 = digsym_w4/2;
    digsym_w5 = digsym_w5/2;
    ittotal_w1 = ittotal_w1/2;
    ittotal_w2 = ittotal_w2/2;
    ittotal_w3 = ittotal_w3/2;
    ittotal_w4 = ittotal_w4/2;
    ittotal_w5 = ittotal_w5/2;
    crtmean_w1 = -50 * crtmean_w1;
    crtmean_w2 = -50 * crtmean_w2;
    crtmean_w3 = -50 * crtmean_w3;
    crtmean_w4 = -50 * crtmean_w4;
    crtmean_w5 = -50 * crtmean_w5;
   
MODEL:
!SPEED
  !individual test levels and slopes

    !Symbol search
     i_symsear s_symsear | symsear_w1@0 symsear_w2@2.98 symsear_w3@6.75 symsear_w4@9.82 
    symsear_w5@12.54;
    !covariance between level and slope
    !i_symsear with s_symsear;
    s_symsear@0; !variables with negative resitdual variances fixed at 0
  

    !Digit symbol coding
    i_digsym s_digsym | digsym_w1@0 digsym_w2@2.98 digsym_w3@6.75 
    digsym_w4@9.82 digsym_w5@12.54;
    !covariance between level and slope
    i_digsym with s_digsym;

    !Inspection time
    i_it s_it | ittotal_w1@0 ittotal_w2@2.98 ittotal_w3@6.75 ittotal_w4@9.82 
    ittotal_w5@12.54;
    !covariance between level and slope
    i_it with s_it;

    !Reaction time
    i_crt s_crt | crtmean_w1@0 crtmean_w2@2.98 crtmean_w3@6.75 crtmean_w4@9.82 
    crtmean_w5@12.54;
    !covariance between level and slope
    i_crt with s_crt;
  
  !processing speed domain level and slope
    i_speed BY i_it i_digsym i_symsear i_crt;
    s_speed BY s_it s_digsym s_symsear s_crt;

!MEMORY
!individual test levels and slopes

    !verbal pairs
     i_vpa s_vpa | vpatotal_w1@0 vpatotal_w2@2.98 vpatotal_w3@6.75 vpatotal_w4@9.82 
    vpatotal_w5@12.54;
    !covariance between level and slope
    i_vpa with s_vpa;

    !logical memory
    i_lm s_lm | lmtotal_w1@0 lmtotal_w2@2.98 lmtotal_w3@6.75 lmtotal_w4@9.82 
    lmtotal_w5@12.54;
    !covariance between level and slope
    !i_lm with s_lm;
    s_lm@0;!variables with negative resitdual variances fixed at 0

    !Digit backwards
    i_digback s_digback | digback_w1@0 digback_w2@2.98 digback_w3@6.75 digback_w4@9.82 
    digback_w5@12.54;
    !covariance between level and slope
    i_digback with s_digback;
  
  !memory domain level and slope
    i_mem BY i_lm i_vpa  i_digback;
    s_mem BY s_lm s_vpa  s_digback;

!Crystallised
  !individual test levels and slopes

    !NART
     i_nart s_nart | nart_w1@0 nart_w2@2.98 narttot_w3@6.75 narttot_w4@9.82 
    narttot_w5@12.54;
    !covariance between level and slope
    !i_nart with s_nart;
    s_nart@0;!variables with negative resitdual variances fixed at 0

    !WTAR
    i_wtar s_wtar | wtar_w1@0 wtar_w2@2.98 wtartot_w3@6.75 wtartot_w4@9.82 
    wtartot_w5@12.54;
    !covariance between level and slope
    !i_wtar with s_wtar;
    s_wtar@0;!variables with negative resitdual variances fixed at 0

    !Verbal fluency
    i_vftot s_vftot | vftot_w1@0 vftot_w2@2.98 vftot_w3@6.75 vftot_w4@9.82 
    vftot_w5@12.54;
    !covariance between level and slope
    i_vftot with s_vftot;
  
  !crystallised domain level and slope
    i_crys BY i_wtar i_nart  i_vftot;
    s_crys BY s_wtar s_nart  s_vftot;

!VISUOSPATIAL
!individual test levels and slopes

    !Block design
     i_blkdes s_blkdes | blkdes_w1@0 blkdes_w2@2.98 blkdes_w3@6.75 blkdes_w4@9.82 
    blkdes_w5@12.54;
    !covariance between level and slope
    i_blkdes with s_blkdes;

    !Matrix reasoning
    i_matreas s_matreas | matreas_w1@0 matreas_w2@2.98 matreas_w3@6.75 matreas_w4@9.82 
    matreas_w5@12.54;
    !covariance between level and slope
    i_matreas with s_matreas;

    !Spatial span
    i_span s_span | spantot_w1@0 spantot_w2@2.98 spantot_w3@6.75 spantot_w4@9.82 
    spantot_w5@12.54;
    !covariance between level and slope
    !i_span with s_span;
    s_span@0;!variables with negative resitdual variances fixed at 0

  !visuospatial domain level and slope
    i_vis BY i_blkdes i_matreas i_span;
    s_vis BY s_blkdes s_matreas s_span;


!!!! ===  General cognitive ability  === !!!!

I_G BY i_vis i_crys i_mem i_speed;
S_G BY s_vis s_crys s_mem s_speed;

!covariance between domains
  i_vis with s_vis;
  i_crys with s_crys;
  i_mem with s_mem;
  i_speed with s_speed;

OUTPUT: STDYX; !get STANDARDIZED ESTIMATES